Funciones › FILTRAR
Función FILTRAR en Excel: cómo filtrar datos con una fórmula
La función FILTRAR devuelve las filas de un rango que cumplen una condición. El resultado aparece en otra parte de la hoja y se extiende solo hacia abajo.
Es un filtro que no hay que volver a aplicar: "muéstrame solo las bebidas", "dame los empleados que ganan más de 15000". Si los datos cambian, la lista cambia con ellos.
La condición se escribe como una comparación sobre una columna completa. Esa columna debe tener el mismo número de filas que el rango que quieres filtrar.
Sintaxis
=FILTRAR(matriz; incluir; [si_vacío]) En inglés: FILTER
matrizEl rango con los datos que quieres obtener. Puede ser una columna o varias, como
A2:C6.incluirLa condición, escrita sobre un rango del mismo alto:
B2:B6="Bebida",C2:C6>=30. Se quedan las filas donde se cumple.si_vacío(opcional)Lo que se muestra si ninguna fila cumple la condición, por ejemplo
"Sin resultados". Si lo omites y no hay coincidencias, aparece un error.
Ejemplos
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Producto | Categoría | Precio | Bebidas | |
| 2 | Café | Bebida | 45 | Café | |
| 3 | Pan dulce | Panadería | 18 | Jugo | |
| 4 | Jugo | Bebida | 38 | Té | |
| 5 | Galletas | Panadería | 25 | ||
| 6 | Té | Bebida | 30 |
E2: =FILTRAR(A2:A6;B2:B6="Bebida") Resultado: CaféDevuelve los productos cuya categoría es Bebida: Café, Jugo y Té.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Producto | Precio | Producto | Precio | |
| 2 | Café | 45 | Café | 45 | |
| 3 | Pan dulce | 18 | Jugo | 38 | |
| 4 | Jugo | 38 | Té | 30 | |
| 5 | Galletas | 25 | |||
| 6 | Té | 30 |
D2: =FILTRAR(A2:B6;B2:B6>=30) Resultado: CaféSi el primer argumento tiene dos columnas, el resultado trae las dos. Aquí, los productos de 30 o más con su precio.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Producto | Categoría | Precio | Bebidas de menos de 40 | |
| 2 | Café | Bebida | 45 | Jugo | |
| 3 | Pan dulce | Panadería | 18 | Té | |
| 4 | Jugo | Bebida | 38 | ||
| 5 | Galletas | Panadería | 25 | ||
| 6 | Té | Bebida | 30 |
E2: =FILTRAR(A2:A6;(B2:B6="Bebida")*(C2:C6<40)) Resultado: JugoPara exigir dos condiciones a la vez, cada una va entre paréntesis y se multiplican. Quedan Jugo y Té.
Practica ahora
Cargando…
Hacer la lección completa: Función FILTRAR →
Errores comunes
- No prever que no haya resultados. Si ninguna fila cumple, aparece el error
#¡CALC!. Agrega el tercer argumento:=FILTRAR(A2:A6;B2:B6="Lácteos";"Sin resultados"). - Rangos de distinto alto. Si los datos van de la fila 2 a la 6, la condición también. Con rangos desiguales la fórmula falla.
- Usar
YuOen la condición. Esas funciones devuelven un solo valor para todo el rango. Dentro deFILTRAR, multiplica las condiciones para "y" y súmalas para "o". - Tener celdas ocupadas donde va el resultado. La lista necesita espacio libre. Si algo estorba, aparece
#¡DESBORDAMIENTO!. - Usarla en una versión antigua.
FILTRARexiste en Excel de Microsoft 365 y desde Excel 2021.
Lecciones para practicar FILTRAR
- Función FILTRAR: Trae solo las filas que cumplen una condición con la función FILTRAR, sin tocar la tabla original.
- Función ORDENAR: Ordena una lista o una tabla entera con la función ORDENAR, en orden ascendente o descendente, por la columna que quieras.