Funciones › SI.CONJUNTO
Función SI.CONJUNTO en Excel: varias condiciones sin anidar
La función SI.CONJUNTO revisa varias condiciones en orden y devuelve el resultado de la primera que se cumple. Sirve para franjas: "¿qué calificación le toca a esta nota?" o "¿qué comisión corresponde a este monto?".
Reemplaza a varios SI uno dentro de otro, con una fórmula más fácil de leer. Si solo hay dos resultados posibles, SI alcanza. Si comparas una celda con una lista de valores exactos, mira CAMBIAR.
Sintaxis
=SI.CONJUNTO(prueba_lógica1; valor1; …) En inglés: IFS
prueba_lógica1La primera condición que se revisa. Ej.:
B2>=9.valor1Lo que devuelve si esa condición se cumple. Después siguen más pares de condición y resultado. Para un caso "si no", usa
VERDADEROcomo última condición.
Ejemplos
| A | B | C | |
|---|---|---|---|
| 1 | Alumno | Nota | Calificación |
| 2 | Olga | 8,4 | Bien |
| 3 | Pablo | 5,2 | |
| 4 | Queta | 9,6 |
C2: =SI.CONJUNTO(B2>=9;"Excelente";B2>=7;"Bien";B2>=6;"Suficiente";VERDADERO;"Insuficiente") Resultado: BienRevisa de izquierda a derecha. 8,4 no llega a 9, pero sí a 7: devuelve "Bien" y deja de revisar.
| A | B | C | |
|---|---|---|---|
| 1 | Vendedor | Ventas | Comisión |
| 2 | Reyes | 18000 | 900 |
| 3 | Solís | 7500 |
C2: =SI.CONJUNTO(B2>=20000;B2*0,08;B2>=10000;B2*0,05;VERDADERO;B2*0,02) Resultado: 900Los resultados pueden ser cálculos. 18000 cae en la segunda franja, la del 5 %: la comisión es 900.
| A | B | C | |
|---|---|---|---|
| 1 | Producto | Existencias | Estado |
| 2 | Tinta | 0 | Agotado |
| 3 | Papel | 14 |
C2: =SI.CONJUNTO(B2=0;"Agotado";B2<10;"Bajo";VERDADERO;"Normal") Resultado: AgotadoLas condiciones no tienen que ser del mismo tipo. La primera es una igualdad: con 0 existencias devuelve "Agotado" sin mirar las demás.
Practica ahora
Cargando…
Hacer la lección completa: Función SI.CONJUNTO →
Errores comunes
- Orden de las condiciones. Si pones primero
B2>=6, una nota de 9,6 se queda en "Suficiente", porque esa condición ya se cumple. Empieza por la más exigente. - Sin caso final. Si ninguna condición se cumple, el resultado es
#N/D. Termina conVERDADEROy el resultado por defecto. - Pares incompletos. Cada condición necesita su resultado. Con un número impar de argumentos Excel no acepta la fórmula. Revisa que vayan de dos en dos.
- Versión de Excel.
SI.CONJUNTOexiste en Microsoft 365 y desde Excel 2019. En versiones anteriores hay que anidarSI.
Lecciones para practicar SI.CONJUNTO
- Función SI.CONJUNTO: Clasifica valores en varios tramos sin anidar fórmulas, usando la función SI.CONJUNTO y una última prueba VERDADERO.