Funciones › BUSCARH

Función BUSCARH en Excel: buscar en tablas horizontales

La función BUSCARH hace lo mismo que BUSCARV, pero en horizontal: busca un valor en la primera fila de una tabla y baja por esa columna hasta la fila que le pidas. Sirve cuando los encabezados están a lo ancho, como los meses de un presupuesto: "¿cuánto se gastó en publicidad en marzo?".

Si tu tabla tiene los datos hacia abajo, con un registro por fila, la función es BUSCARV. BUSCARX sirve para los dos casos.

Sintaxis

=BUSCARH(valor_buscado; matriz_tabla; indicador_filas; [rango]) En inglés: HLOOKUP

valor_buscado: Lo que buscas en la primera fila de la tabla: un encabezado o la celda que lo contiene. Ej.: B6.
matriz_tabla: La tabla completa, con la fila de encabezados incluida. Ej.: A1:D4.
indicador_filas: El número de la fila que quieres traer, contando desde 1 a partir de la primera fila de la tabla.
rango (opcional): FALSO para coincidencia exacta, que es lo habitual. VERDADERO, o nada, para coincidencia aproximada, que exige la primera fila ordenada de menor a mayor.

Ejemplos

	A	B	C	D
1	Concepto	Enero	Febrero	Marzo
2	Publicidad	1200	950	1400
3	Sueldos	8000	8000	8200
4	Alquiler	1500	1500	1500
5
6	Mes	Marzo
7	Publicidad	1400

B7: =BUSCARH(B6;A1:D4;2;FALSO) Resultado: 1400

Busca "Marzo" en la fila 1 y devuelve el valor de la segunda fila de la tabla, la de publicidad: 1400.

	A	B	C	D
1	Concepto	Enero	Febrero	Marzo
2	Publicidad	1200	950	1400
3	Sueldos	8000	8000	8200
4	Alquiler	1500	1500	1500
5
6	Sueldos de febrero	8000

B6: =BUSCARH("Febrero";A1:D4;3;FALSO) Resultado: 8000

Cambia el tercer argumento y trae otra fila. El encabezado buscado se puede escribir dentro de la fórmula, entre comillas.

	A	B	C	D
1	Unidades desde	1	50	200
2	Precio unitario	12	10,5	9
3
4	Unidades	120
5	Precio	10,5

B5: =BUSCARH(B4;B1:D2;2;VERDADERO) Resultado: 10,5

Con VERDADERO busca por franjas. 120 unidades caen en el tramo que empieza en 50, con un precio de 10,5.

Practica ahora

Cargando…

Hacer la lección completa: Función BUSCARH →

Una escuela guarda las notas por trimestre, con un trimestre en cada columna.

En G2, trae la nota de Matemáticas del trimestre de G1 con =BUSCARH(G1;A1:D4;2;FALSO).

Ahora sin la fórmula lista.

En G3, trae la nota de Historia del mismo trimestre.

Errores comunes

Olvidar el cuarto argumento. Sin él, la búsqueda es aproximada y puede devolver la columna equivocada sin avisar. Para buscar encabezados exactos, termina con FALSO.
Contar mal la fila. El tercer argumento es la posición dentro de la tabla, no el número de fila de la hoja. Si la tabla empieza en la fila 3, su primera fila sigue siendo la 1.
Dejar fuera la fila de encabezados. BUSCARH busca en la primera fila del rango. Empieza el rango en la fila donde están los encabezados.
Error #N/D. El encabezado no existe o está escrito distinto, por ejemplo "Mar" frente a "Marzo". Revisa que el texto buscado sea igual al de la tabla.
Usarla en una tabla vertical. Si cada registro ocupa una fila y los campos están en columnas, la función correcta es BUSCARV.

Lecciones para practicar BUSCARH